home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / TEX-UTIL / DVIVIEW / TEXFONTS5 / !TeXFonts / NotRISCOS / comlig / mf
Text File  |  1988-02-26  |  2KB  |  61 lines
  1. % This is COMLIG.MF in text format, as of Mar 31, 1986.
  2. % This file defines characters common to roman and italic text fonts
  3. % that appear only when |ligs>0|.
  4.  
  5. % Character codes \0042, \0055, \0134, \0173, and \0174 are generated.
  6.  
  7. ligtable "`": "`"=:oct"134";
  8. ligtable "'": "'"=:oct"042", "?" kern 2u#, "!" kern 2u#;
  9.  
  10. ligtable "-": "-"=:oct"173";
  11. ligtable oct"173": "-"=:oct"174";
  12.  
  13. cmchar "Closing quotes";
  14. beginchar(oct"042",7u#+max(2u#,dot_size#),asc_height#,0);
  15. italcorr asc_height#*slant+dot_size#-4.1u#;
  16. adjust_fit(0,0);
  17. x1-.5dot_size=hround .6u; y2+.5dot_size=h;
  18. x2-x1=hround(1.5u+max(2u,dot_size)); y2=y1;
  19. comma(1,a,dot_size,.25u,comma_depth); % left dot and tail
  20. comma(2,b,dot_size,.25u,comma_depth); % right dot and tail
  21. penlabels(1,2); endchar;
  22.  
  23. cmchar "Hyphen";
  24. beginchar("-",6u#,x_height#,0);
  25. italcorr .5x_height#*slant-.5u#;
  26. adjust_fit(0,0);
  27. numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
  28. pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
  29. top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
  30. if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
  31. filldraw stroke z1e--z2e;  % bar
  32. penlabels(1,2); endchar;
  33.  
  34. cmchar "Opening quotes";
  35. beginchar(oct"134",7u#+max(2u#,dot_size#),asc_height#,0);
  36. italcorr asc_height#*slant-.1u#;
  37. adjust_fit(0,0);
  38. x2+.5dot_size=hround(w-.6u); y1+.5dot_size=h-comma_depth;
  39. x2-x1=hround(1.5u+max(2u,dot_size)); y2=y1;
  40. ammoc(1,a,dot_size,.25u,comma_depth); % left dot and tail
  41. ammoc(2,b,dot_size,.25u,comma_depth); % right dot and tail
  42. penlabels(1,2); endchar;
  43.  
  44. cmchar "En dash";
  45. beginchar(oct"173",9u#,x_height#,0);
  46. italcorr .61803x_height#*slant+.5u#;
  47. adjust_fit(0,0);
  48. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  49. top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
  50. filldraw stroke z1e--z2e;  % bar
  51. penlabels(1,2); endchar;
  52.  
  53. cmchar "Em dash";
  54. beginchar(oct"174",18u#,x_height#,0);
  55. italcorr .61803x_height#*slant+.5u#;
  56. adjust_fit(letter_fit#,letter_fit#);
  57. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  58. top y1r=top y2r=vround(.61803h+.5vair); lft x1=-eps; rt x2=w+eps;
  59. filldraw stroke z1e--z2e;  % bar
  60. penlabels(1,2); endchar;
  61.